Feature +lblz, +nasal, +long, +longacc, +trema
Feature (syllable) +stress
Feature (syllable) +nonumlauting

Feature type(vowel, consonant)

Feature voicing(unvoiced, voiced)
Feature place(bilabial, labial, dental, alveolar, postalveolar, palatal, velar, uvular, glottal)
Feature manner(stop, fricative, nasal, approximant, trill)

Feature height(low, lowmid, mid, highmid, high)
Feature frontness(front, central, back)
Feature rounded

# Consonants

Symbol § [consonant]
Symbol µ [vowel]
Symbol n [consonant voiced alveolar nasal]
Symbol m [consonant voiced labial nasal]
Symbol ŋ [consonant voiced velar nasal]
Symbol ɲ [consonant voiced palatal nasal]
Symbol s [consonant unvoiced alveolar fricative]
Symbol z [consonant voiced alveolar fricative]
Symbol t [consonant unvoiced dental stop]
Symbol þ [consonant unvoiced dental fricative]
Symbol ð [consonant voiced dental fricative]
Symbol d [consonant voiced dental stop]
Symbol w [consonant voiced labial approximant]
Symbol x [consonant unvoiced velar fricative]
Symbol l [consonant voiced alveolar approximant]
Symbol b [consonant voiced labial stop]
Symbol ɣ [consonant voiced velar fricative]
Symbol k [consonant unvoiced velar stop]
Symbol j [consonant voiced palatal approximant]
Symbol ʃ [consonant unvoiced postalveolar fricative]
Symbol r [consonant voiced alveolar trill]
Symbol ʁ [consonant voiced uvular fricative]
Symbol ɦ [consonant voiced glottal fricative]
Symbol p [consonant unvoiced labial stop]
Symbol f [consonant unvoiced labial fricative]
Symbol v [consonant voiced labial fricative]
Symbol ç [consonant unvoiced palatal fricative]

# Vowels
Symbol ə [vowel mid central]
Symbol a [vowel low front -rounded]
Symbol ɑ [vowel low back -rounded]
Symbol e [vowel mid front -rounded]
Symbol ɛ [vowel lowmid front -rounded]
Symbol œ [vowel lowmid front +rounded]
Symbol ɪ [vowel highmid front -rounded]
Symbol i [vowel high front -rounded]
Symbol o [vowel mid back +rounded]
Symbol ɔ [vowel lowmid back +rounded]
Symbol u [vowel high back +rounded]
Symbol ʏ [vowel high front +rounded]

Diacritic ̄ (floating) [+longacc]
Diacritic ̃  (floating) [+nasal]
Diacritic ʷ [+lblz]
Diacritic ː [+long]
Diacritic ˈ (before) [+stress]
Diacritic ₋ (before) [+nonumlauting]
Diacritic ̈ (floating) [+trema]

Class mainvowel {a, e, i, o, u}
Class accvowel {ɑ, ɛ, ɪ, ɔ, ʏ}
Class liquid {l, r, w, u, ʋ, ʁ}

Syllables:
 explicit

textfixes:
 y => j
 [+lblz]&!{[unvoiced velar fricative]} * => [-lblz] w
 ' => [+stress]
 Then:
  ' => *

# WMAL
sleta: # ē in stressed syllables lowered to ā
 e&[+long +stress] => ɑː / $ [consonant]* _
ulblz: # u labialization
 u => w / {. [consonant] !. _ !. [vowel], $ _ !. [vowel]}
dlblzewi: # The delabialization of all labiovelar consonants except word-initially.
 [labial] => [-lblz] / $ _
zdwtww: # -zw- => -ss- and -ðw- => -dd-
 {z, ð}$1 . w => $1 . $1
 . {z, ð}$1 w => $1 . $1
 Then:
  z . z => s . s
  ð . ð => d . d
ethbd: #[ð], the fricative allophone of /d/, becomes [d] in all position
 ð => d
lopmzwf: # Loss of Proto-Mallian /z/ word-finally
 z => * / _ $
lofa: # Loss of final -a
 ɑ&[-stress] => ə / _ $ // $ [consonant]* [vowel]* _
etibij: # *e to i before i and j.
 e {iː, i, j} => * iː

# OLD MALLIAN
diphtongues:
 {ɑ} {i, j} => ɛ i
 i j => [+long] *
 u w => [+long] *
 j => i / [vowel] !. _ // $ _
 w => u / [vowel] !. _ // $ _
 i => j / $ _ !. [vowel]
 u => w / $ _ !. [vowel]
pmoaebduoaieiss: # Proto-Mallian ō and ē become diphtongues uo and ie in stressed syllables
 {eː, ɔː}&[+stress] => {ie, uɔ}
jilwftc: # /j/ is lost when following two consonants
 j => * / [consonant] [consonant] _
fodv: # Final obstruent devoicing
 {[stop], [fricative]}&[voiced] => [unvoiced] / _ $
xdbv: # /x/ disappears between vowels
 x => * / [vowel] !. _ !. [vowel] // * _
xsbgs: # /xs/ becomes a geminated ss
 xs => ss
 sz => ss
 Then:
  s !. s . s => * * s . s
ztr: # /z/ => /r/
 z => s / [consonant unvoiced] !. _
 z => r // $ _
wfvs: #Word-final vowel stuff
 uː => ɔː / _ $
 [high +long -stress] => [-long] / _ $
wlbcav: # /w/ lost between consonant and unstressed vowel
 w => * / [consonant] . _ [vowel -stress]
uerdingen:
 k => x / _ $
romanizer-old-mallian:
 [+stress] => [-stress]
 [+nonumlauting] => [-nonumlauting]
 Then:
  . => *
 Then:
  [+long] => [-long +longacc]
 Then:
  {§,µ} => \-

#MIDDLE MALLIAN
idiphmerge:
 {ɑ, e, ɔ, u} => ə / i _
fttxt: # /ft/ => /xt/
 ft => xt
x-lblz:
 n [unvoiced velar fricative +lblz] => ŋ
 [unvoiced velar fricative +lblz] => w / $ _
 [unvoiced velar fricative +lblz] => ɣ / _ *
 [unvoiced velar fricative +lblz] => x
 x => [voiced glottal] / $ _
vfbvsi: # Voiceless fricatives become voiced syllable-initially
 [fricative]$1 => [voiced] / . _ // {$1 _, _ [unvoiced], _ {n, m, @liquid}}
backshortumlaut:
 [back -long] => [front] / _ {[consonant]}+ i // {[vowel] _, _ [vowel]}
 Then:
  œ => ɛ
i-umlaut:
 [low -nonumlauting] => [mid] / _ {[consonant]}+ i // {[vowel] _, _ [vowel]}
osl: # Open syllable lengthening
 [vowel +stress -long] => [+long] / _ . // {[vowel] _, _ [vowel]}
vsh1: # Vowel shifts 1
  {ɪː, ʏː, ɑː, ɛː, ɔː, iː, uː, əː, eu, {e, ɛ} i} => {i, ɔː, aː, eː, oː, i, oː, ə, øː, ɑ i} // {[vowel] _, _ [vowel]}
  {a, e, o, u}&[+stress] => {aː, eː, oː, ʏː} / _ . // {[vowel] _, _ [vowel], _ $, _ !. [consonant]}
  {a, e, i, o, u} => {ɑ, ɛ, ɪ, ɔ, ʏ} // {[vowel] _, _ [vowel]}
dfbs: # Dental fricatives become stops
 [dental fricative] [dental fricative] => s s
 [dental fricative] => [stop]
fnv: # Final nasal vowel:
 {nɑ̃, lɑ̃, rɑ̃} => {ən, əl, ər}
 . ə̃ => *
 ə̃ => ə
fvschwa: # Final vowel schwa
 [vowel] => ə / _ $ // {[vowel] !. _, $ [consonant]* _}
schwamtth: # Schwa metathesis
 {n, r, l}$1 ə => ə $1 / {[stop], [fricative]} _
romanizer-middle-mallian:
 [+stress] => [-stress]
 [+nonumlauting] => [-nonumlauting]
 Then:
  . => *
 Then:
  [+long] => [-long +longacc]
 Then:
  {§,µ} => \-

# LATE CEMFS
vsh2: # Vowel shifts 2
 [vowel +long]&!{[high front -rounded], [highmid front -rounded]} => ɑu / _ {w, ə}
 @accvowel&[+long] u => @mainvowel *
nasaln: # Nasal to -n
 [+nasal] * => [-nasal] n
usvs: # Unstressed short vowel becomes schwa
 @accvowel&[-stress]&!{ɪ} => ə // {[vowel] _, _ [vowel], $ [consonant]* [vowel]* _, _ !. [consonant]&!{n, m, @liquid}}
svfbsg: # Short vowel followed by schwa gemination
 * . [consonant]$1 => $1 . $1 / {![vowel], $} @accvowel _ ə
sktsx: # /sk/ => /sx/
 s !. k => s * x
 {k, x} {x} => x x
 {x} {k, x} => x x
gachtsj:
 ɣ . ɣ => * . ç
 x . x => ç . ç
 {x, ɣ} => ç / _ .
 s . k => ç . k
 x => k
s-methathesis:
 [vowel]$2 . s !. [consonant]$1&!{n, m, l, w, j, r} => $2 * $1 . s / _ ![consonant]
 s !. [consonant]$1&!{n, m, l, w, j, r} => $1 * s / _ ![consonant]
lenition-dental:
 {t t, d d } => {þ þ, ð ð}
 {t, d} => {þ, ð} / _ . // _ . {t, d}
longvowel-u-to-w:
 u => w / [+long] _

romanizer-late-cemfs:
 [+stress] => [-stress]
 [+nonumlauting] => [-nonumlauting]
 Then:
  . => *
 Then:
  [+long] => [-long +longacc]
 Then:
  {§,µ} => \-

final-merges:
 r => ʁ
 øː => ø
romanizer-cemfs:
 i => i / [+long] _
 {ɑu, ɛi, {ø, eu}, ɑ i, i} => {au, y, eu, ai, ie}
 @accvowel => {a, e, i, o, u} / _ [consonant]$1 $1
 @accvowel => {a, e, i, o, u} / {_ !. [consonant]}
 @accvowel => {â, ê, i, ô, û}
 {aː, eː, iː, oː, uː} => {á, é, ii, ó, ú}
 {a, e, i, o, u} => {A, E, I, O, U} # error catching
 {xx} => {cch}
 {ɣ, ɦ, ʁ, ŋ, x, k} => {g, h, r, ng, ch, c}
 {§, µ} => \-
 Then:
  . => *
 Then:
  [+stress] => [-stress]
  [+nonumlauting] => [-nonumlauting]
 Then:
  {a, e, i, o, u} .? ə => [vowel +trema] * *